Flash Led Project PIC 12F675


;----------------------------------------------------------------------
; NAME: Flash Led for     PIC 12F675
; BY:     Arun.s 
; WEB:  http://www.3gesoft.blogspot.com
;----------------------------------------------------------------------


; config. GPIO xx543210 = xx00 1100

; vers 0.1    25.03.2006

    list      p=12f675            ; list directive to define processor
    #include <p12f675.inc>        ; processor specific variable definitions

;----------------------------------------------------------------------
; Configurare
    __CONFIG _INTRC_OSC_NOCLKOUT & _WDT_OFF & _PWRTE_ON & _MCLRE_OFF & _CP_OFF & _CPD_OFF
    ERRORLEVEL -302
;----------------------------------------------------------------------

;----------------------------------------------------------------------
; Constant define
;----------------------------------------------------------------------
#define Led4        GPIO,0        ; (o) led yellow / gelb / galben
#define Led3        GPIO,1        ; (o) led red / rot / rosu

#define rezerva        GPIO,2        ; (i) not connected

#define swNext        GPIO,3        ; (i) intrare switch next ( not implemented )
#define    Led2        GPIO,4        ; (o) led red / rot / rosu
#define    Led1        GPIO,5        ; (o) led yellow / gelb / galben

;----------------------------------------------------------------------
; RAM VARIABLES DEFINITIONS
;----------------------------------------------------------------------
; Bank0 = 20h-5Fh

    CBLOCK    0x020
; -------------------
; delays
    delayCnt:  1    ; contor delay 100uS
    delayCnt1: 1    ; contor delay 10mS
    delayCnt2: 1    ; contor delay 1S
; -------------------
; alte variabile ..
    cntFlash: 1        ; contor flash

    ENDC

;----------------------------------------------------------------------
; MACRO DEFINITIONS
;----------------------------------------------------------------------
; Selects register bank 0
BANK0 MACRO
    BCF    STATUS,RP0    ; clear bank select bits
    ENDM
;----------------------------------------------------------------------
; Selects register bank 1
BANK1 MACRO
    BSF    STATUS,RP0    ;
    ENDM

;----------------------------------------------------------------------
; disable global irq
DISABLE_IRQ MACRO
    LOCAL STOP_INT
STOP_INT
    BCF    INTCON,GIE    ; Disable global interrupt
    BTFSC INTCON,GIE    ; check if disabled
    GOTO STOP_INT        ; nope, try again
    ENDM
;----------------------------------------------------------------------
; enable global irq
ENABLE_IRQ MACRO
    LOCAL    START_INT
START_INT   
    BSF    INTCON,GIE    ; Enable global interrupt
    BTFSS INTCON,GIE    ; check if disabled
    GOTO START_INT        ; nope, try again
    ENDM

;----------------------------------------------------------------------
; macro definitions / comands / comenzi ..

Led1_ON MACRO
    bsf Led1
    nop
    ENDM

Led1_OFF MACRO
    bcf Led1
    nop
    ENDM


Led2_ON MACRO
    bsf Led2
    nop
    ENDM

Led2_OFF MACRO
    bcf Led2
    nop
    ENDM


Led3_ON MACRO
    bsf Led3
    nop
    ENDM

Led3_OFF MACRO
    bcf Led3
    nop
    ENDM

Led4_ON MACRO
    bsf Led4
    nop
    ENDM

Led4_OFF MACRO
    bcf Led4
    nop
    ENDM
;----------------------------------------------------------------------
; END macro definitions
;----------------------------------------------------------------------


;**********************************************************************
;  PROGRAMUL
;**********************************************************************
    ORG     0x000               ; processor reset vector
    goto    MAIN                ; go to beginning of program

;-----------------------------------------------------------------------------
;    Interrupt service routine
;-----------------------------------------------------------------------------
    ORG     0x004              ; interrupt vector location
    RETFIE                ; return from interrupt

;-----------------------------------------------------------------------------
;     MAIN ROUTINE START HERE
;-----------------------------------------------------------------------------
    ORG     0x010
MAIN:
;-----------------------------------------------------------------------------
; Init_Prog
;  - Initialize program & setups
;  - Initilaize all ports to known state before setup routines are called
;-----------------------------------------------------------------------------
Init_Prog:
; int osc calibration / Calibrarea oscilatorului intern de 4 Mhz
    BANK1
    call    0x3FF        ; get the calibration value
    movwf     OSCCAL
    BANK0
; disable irqs / dezactivare intreruperi
    DISABLE_IRQ
; ports init / initializare porturi
    call Init_Ports
; leds off / initializari leduri
    call Init_Led
; init.end / ok, la munca!

;-----------------------------------------------------------------------------
; Program loop start here (forever_loop)
;-----------------------------------------------------------------------------
Prog_Loop:
    ; back to BANK0 / revin la Bank-ul 0
    BANK0

    movlw 0x05
    movwf cntFlash

flash1        ; flash mode 1
    Led1_ON
    call Delay_100mS
    Led1_OFF
    call Delay_100mS

    Led2_ON
    call Delay_100mS
    Led2_OFF
    call Delay_100mS

    Led3_ON
    call Delay_100mS
    Led3_OFF
    call Delay_100mS

    Led4_ON
    call Delay_100mS
    Led4_OFF
    call Delay_100mS


    Led4_ON
    call Delay_100mS
    Led4_OFF
    call Delay_100mS


    Led3_ON
    call Delay_100mS
    Led3_OFF
    call Delay_100mS


    Led2_ON
    call Delay_100mS
    Led2_OFF
    call Delay_100mS


    Led1_ON
    call Delay_100mS
    Led1_OFF
    call Delay_100mS

    decfsz cntFlash, f
    goto flash1
; end 1

    call Init_Led
    call Delay_100mS
   
    movlw 0x10
    movwf cntFlash
flash2         ; flash mode 2
    Led1_ON
    Led4_ON
    call Delay_100mS

    Led1_OFF
    Led4_OFF
    call Delay_10mS
   
    Led1_ON
    Led4_ON
    call Delay_100mS

    Led1_OFF
    Led4_OFF
    call Delay_10mS
    call Delay_10mS


    Led2_ON
    Led3_ON
    call Delay_100mS

    Led2_OFF
    Led3_OFF
    call Delay_10mS
   
    Led2_ON
    Led3_ON
    call Delay_100mS

    Led2_OFF
    Led3_OFF
    call Delay_10mS
    call Delay_10mS

    decfsz cntFlash, f
    goto flash2
; end 2


    call Init_Led
    call Delay_100mS
   
    movlw 0x10
    movwf cntFlash

flash3    ; flash mode 3
    Led1_ON
    Led3_ON
    call Delay_100mS

    Led1_OFF
    Led3_OFF
    call Delay_10mS
   
    Led1_ON
    Led3_ON
    call Delay_100mS

    Led1_OFF
    Led3_OFF
    call Delay_10mS
    call Delay_10mS


    Led2_ON
    Led4_ON
    call Delay_100mS

    Led2_OFF
    Led4_OFF
    call Delay_10mS
   
    Led2_ON
    Led4_ON
    call Delay_100mS

    Led2_OFF
    Led4_OFF
    call Delay_10mS
    call Delay_10mS

    decfsz cntFlash, f
    goto flash3
; end 3

    goto Prog_Loop

;-----------------------------------------------------------------------------
; Library / PROCEDURI
;-----------------------------------------------------------------------------

;-----------------------------------------------------------------------------
; Delay 1S
;-----------------------------------------------------------------------------
Delay_1S:                    ; Call = 2 cycles
    movlw    d'100'                ; 1 cycles
    movwf    delayCnt2            ; 1 cycles
Delay_1S_1:
    call    Delay_10mS            ; 2 cycles
    decfsz    delayCnt2,f            ;
    goto    Delay_1S_1            ; 1+2 cycles
    return

;-----------------------------------------------------------------------------
; Delay 100 mS
;-----------------------------------------------------------------------------
Delay_100mS:                    ; Call = 2 cycles
    movlw    d'10'                ; 1 cycles
    movwf    delayCnt2            ; 1 cycles
Delay_100mS_1:
    call    Delay_10mS            ; 2 cycles
    decfsz    delayCnt2,f            ;
    goto    Delay_100mS_1            ; 1+2 cycles
    return

;-----------------------------------------------------------------------------
; Delay 10 mS
;-----------------------------------------------------------------------------
Delay_10mS:                        ; Call = 2 cycles
    movlw    d'100'                ; 1 cycles
    movwf    delayCnt1            ; 1 cycles
Delay_10mS_1:
    call    Delay_100uS            ; 2 cycles
    decfsz    delayCnt1,f            ;
    goto    Delay_10mS_1        ; 1+2 cycles
    return

;-----------------------------------------------------------------------------
; Delay 100 uS = (5+(3*Constant))*OSC/4
;-----------------------------------------------------------------------------
Delay_100uS:                    ; Call = 2 cycles
    movlw    d'31'                ; 1 cycle
    movwf    delayCnt            ; 1 cycle
    decfsz    delayCnt,f            ;
    goto    $-1                    ; 1+2 cycles
    return                        ; 2 cycles

;-----------------------------------------------------------------------------
; Port init / Initialize Port
;-----------------------------------------------------------------------------
Init_Ports:
    BANK0                ; Bank 0
    clrf    GPIO            ; 1)Status of pins:  GPIO (GPIO=0 <ViL, =1 >ViH)
    movlw    b'00000111'        ; 2)Comparator configuration
    movwf    CMCON            ; Set GP<2:0> digital IO (comparator Off)
    BANK1                ; Bank 1
    bcf     OPTION_REG,5        ; 3)TMR0 clock source select:  Internal instruction cycle clock (CLKOUT)
    bsf    OPTION_REG,7        ; 4)GPIO pull-ups: is disabled
    clrf    WPU            ; 5)Clear weak pull-up register
    clrf    IOC            ; 6)Clear Interrupt-on-change register

;-----------------------------------------------------------------------------
; Port setup GP0-GP5
;-----------------------------------------------------------------------------
;GP0 (Led Y)        act as output
;GP1 (Led R)        act as output (eventual rezerva)
;GP2 (NC)            act as input - rezerva
;GP3 (switch)        can be input only
;GP4 (Led R)        act as output
;GP5 (Led Y)        act as output
;-----------------------------------------------------------------------------

    movlw   b'00001100'        ; 7) data direction TRISO 0: output, 1: input (Hi-Z mode)
    movwf   TRISIO             ; {0,0,GPIO<5:0>} 0-Output 1-Input
; * 12F675 Only *            ; initializaz registrul de selectare a intrarilor analogice
    clrf ANSEL                ; 8)* xxxx ANS<3..0> =0 digital I/O, =1 analog input   
    ;
    BANK0
    return
;-----------------------------------------------------------------------------

;-----------------------------------------------------------------------------
; Initialize Leduri
;-----------------------------------------------------------------------------
Init_Led:
    Led1_OFF
    Led2_OFF
    Led3_OFF
    Led4_OFF
    return
;-----------------------------------------------------------------------------
; calibrarea oscilator intern
;-----------------------------------------------------------------------------
    org 3FFh
; [34]9Ch for  pic 12F675
    retlw 0x9C    ;
;-----------------------------------------------------------------------------
    END                    ; directive 'end of program'
;-----------------------------------------------------------------------------

Comments

Post a Comment

Popular posts from this blog

Download Huawei Modem Unlocker v5.8.1b by BOJS

Image
  Bojs is a very popular team for unlocking the Huawei Modem. Bojs and team has made a beautiful tool to unlock huawei modems for free. This tool name is Huawei Modem Unlocker V5.8.0b and can be downloaded from the link which is provided at the end of the article. This tool can be used to unlock any Huawei Modem without any advance knowledge and so simple to use also. So, just go ahead and download this beautiful tool to unlock your Huawei Non-customised modems for free. Note : Newer versions of Huawei Modem like E367, E173s which have different algorithm, can not be unlocked with this tool. That modems which has Customized Firmware, can not be unlock with this tool. That type of modems can be unlocked via firmware up gradation only. Features of Huawei Modem Unlocker By Bojs V5.8.1b: 1. Smart Unlocking of Huawei Modems (OLD firmwares) 2. Smart Temporary Unlocking of Huawei Modems (NEW firmwares) 3. Upgrade Download/Upload speed of SOME Huawei modems. 4. Enable
Read more

Hidden Secret Service Menu Codes for Sony, Samsung, LG and Philips TV

Image
All digital TVs contain a secret service menu/mode which allows you to change various internal settings such as picture height, width, position, colors, blue back screen, etc. This secret service menu also allows you to enable or disable lots of features in your television set. Basically this service menu is used by TV mechanics. Today in this topic, we are going to share codes to access the hidden secret service menu/mode in Sony, Samsung, LG and Philips TV . These codes will work in all types of TV such as CRT, LCD, LED, Plasma, etc. NOTE 1:  Please note down the default values before changing them, so that you can restore them in future if something goes wrong or you don't like the output. NOTE 2:  Be very careful while playing with these service menus. Better to make changes and check their effects first. Don't save the changes immediately. If something goes wrong, just switch off the TV and switch on it again, it'll restore default settings. Service Menu Cod
Read more

Solving power supply problems (s.m.p.s)

Image
Most problems with equipment using switch mode power supply (s.m.p.s) like television and monitor are power related, this is because power supplies runs under considerable stress due to high voltages and current involved around these circuits. In order to understand how to solve s.m.p.s problem I am going to show you how to analyze common failure mode in CRT television, you can use this principle in repairing CRT monitor too. Case One: CRT Television Dead Here dead I mean the set does not show any sign of life, power ON LED is not lighted and nothing happens even after power is switched on. First confirm the television power cable is not broken inside, you can check this by measuring the voltage across the AC power input connector on the circuit board. If the voltage is reaching the circuit board, then look for the fuse and see if it is blown, if the fuse is okay check also the surge limiter is open or not. If these two components are okay then most likely there is no
Read more